vlookup函式怎麼用詳細步驟

vlookup函式是一個非常強大的函式，在辦公中會經常使用到，根據使用的情況可以做到不一樣的效果，使用方便。下面就為你帶來了vlookup函式怎麼用詳細步驟，快來學習吧。

1、基本用法

引數介紹：

VLOOKUP（找什麼，在哪找，找到後返回其右側對應的第幾列資料，精確還是模糊查詢）

注意：

需要說明的一點是，Excel中的幫助資訊也有錯誤，比如在插入函式功能中VLOOKUP第四引數的說明就是錯的，大家注意不要被誤導哦！如下圖：

2、單條件查詢

在E2單元格輸入=VLOOKUP(D2,$A$2:$B$12,2,0)

引數解釋：

=VLOOKUP(要查詢的銷售員,包含銷售員和其銷售額的資料來源區域,找到後返回第2列,精確查詢)

第一引數：找什麼（或者說按什麼查詢），按銷售員查詢，所以輸入D2

第二引數：在哪找，資料來源區域在A:B列，所以輸入$A$2:$B$12

第三引數：找到後返回第幾列，我們要查詢的是銷售額，銷售額位於B列，即第二引數中的第二列，所以輸入2

第四引數：這裡要精確查詢，所以輸入0

3、藉助名稱框查詢

選擇A2:B12區域定義為查詢區域，在E2單元格輸入=VLOOKUP(D2,查詢區域,2,0)

注意：

利用名稱框抓取資料區域，就不用在手工去選擇區域（名稱框適用於工作簿中所有的工作表）

4、查詢返回多列資料

要求：

左側表格是資料來源區域，需要在右側區域根據姓名調取對應的資料，黃色區域是需要填寫公式的區域

選中H2:K5單元格區域，輸入以下公式=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)後按Ctrl+Enter組合鍵

5、多條件查詢（一對多查詢）

首先在A列增加輔助列，利用COUNT與&組合，在A2輸入=C2&COUNTIF($C$2:C2,C2)

選擇F9:H15單元格輸入=VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0)，再按Ctrl+Enter

最後為避免出現錯誤值，要在外面加上IFERROR函式，=IFERROR(VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0),"")

6、從右到左查詢（反向查詢）

要求：

需要按照給出的編號查詢對應的銷售員姓名，黃色區域輸入公式

資料來源格式不允許改動時

在F2單元格輸入=VLOOKUP(E2,IF({1,0},$B$2:$B$12,$A$2:$A$12),2,0)

此處IF函式，重新構建了一個區域，將$B$2:$B$12放到第一列，$A$2:$A$12放到第二列，查詢並返回對應資料

當IF的第一引數是{1,0}時，相當於把條件成立的和不成立的放到一起，構建為一個記憶體陣列，

1代表條件成立的時候，0代表條件不成立的時候，{1,0}形成2列，相當於B列與A列互換位置

3、區間查詢

要求：

需要按照等級劃分規則，將成績劃分到其對應的等級中

建立輔助列

注意：必須是升序排列

此函式的最後一個引數可以隱藏（不輸入），或者輸入1

在C2單元格輸入 =VLOOKUP(B2,$I$2:$J$5,2)，將此公式展開是這樣的： =VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)

8、萬用字元模糊查詢

此方法只適用於有唯一一個符合條件的值，否則用SUMIF比較好

vlookup的作用：

vlookup 用於查詢指定值所對應的另一個值。例如：查詢某件產品的價格，某個同學的某科成績等。

vlookup 函式表示：

=vlookup（要查詢的值，查詢區域，返回值所在列號，精確匹配或近似匹配）

引數說明：

1、要查詢的值：可以引用單元格的值，例如B6;也可以直接輸入，例如“紅色T恤”。

2、查詢區域：用於指定查詢範圍，例如A2:D10。

3、返回值所在列號：用於指定返回值在哪列，列號開始必須從指定範圍算起，

例如指定範圍為B2:E8，則 B 列為第一列，若返回值所在列號為 3，則從 D 列中返回值。

4、精確匹配或近似匹配：精確匹配用 0 或 False 表示，近似匹配用 1 或 True 表示，

為“可選”項，即可填可不填，若不填，則預設值為近似匹配。